抽象クラスとポリモーフィズム

　抽象クラスを使用してポリモーフィズムを実現させてみましょう。スーパークラスの型でサブクラスのオブジェクトを扱えることを思い出してください。抽象クラスの型で、抽象クラスを実装したオブジェクトを格納することができます。ただしその場合、呼び出すことができるのは抽象クラスで定義しているメンバだけです。

　これからいろいろな乗り物を操作できるシミュレーターを作成してみましょう。乗り物クラスを継承したスポーツカークラス、タクシークラスを作成して利用してみましょう。ポリモーフィズムを確認するために、乗り物のテストをするテストドライバークラスを作成して、テストドライバーが乗り物を動かすようにします。

　「AbstructClassTest」プロジェクトを修正して作成しましょう。AbstructClassTestフォルダーをコピーして、作成するプロジェクト名にフォルダー名を変更してください。

　次に、乗り物クラスを継承したタクシークラスを作成しましょう。

プロジェクトの種類	コンソールアプリケーション
プロジェクト名	AbstractPlymoTest

Public Class Taxi
　Inherits Vehicle
　'フィールド==========
　Private MaxSpeed As Integer '最大スピード
　'プロパティ==========
　Public Property Unchin As Integer　　　　　'売上金額
　Public Property Distance As Double　　　　　'走行距離
　Public Property Aboard As Boolean　　　　　'乗車状態
　'コンストラクタ==========
　Public Sub New(gas As Double, maxspeed As Integer)
　　MyBase.New(gas)
　　'ガソリン量が容量を超えている場合は、最大容量をガソリン残量にセット
　　If Me.Gas > 70 Then
　　　Me.Gas = 70
　　End If
　　Me.MaxSpeed = maxspeed
　End Sub
　'メソッド==========
　Public Overrides Sub SpeedUp(sp As Integer)
　　'消費するガソリンがない場合は加速しない
　　If Not ((Me.Gas - sp / 20.0) <= 0) Then
　　　'加速
　　Me.Speed += sp
　　　Me.Gas -= sp / 20.0
　　End If
　　'スピードが最大スピードを超えていたら、最大スピードにセット
　　If Me.Speed > Me.MaxSpeed Then
　　　Me.Speed = Me.MaxSpeed
　　End If
　End Sub
　Public Function RideToTaxi(price As Integer, distance As Double) As String
　　'乗車中かどうか
　　If Me.Aboard Then
　　　Return "乗車中です。"
　　End If
　　'走行中かどうか
　　If Me.Speed <> 0 Then
　　　Return "停車してください。"
　　End If
　　'運賃、距離を加算
　　Me.Unchin += price
　　Me.Distance += distance
　　Me.Aboard = True
　　Return Nothing
　End Function
　Public Function GetOffTaxi() As String
　　'乗車中かどうか
　　If Not Me.Aboard Then
　　　Return "乗車していません。"
　　End If
　　'走行中かどうか
　　If Me.Speed <> 0 Then
　　　Return "停車してください。"
　　End If
　　'乗車の状態を変更
　　Me.Aboard = False
　　Return Nothing
　End Function
End Class

　4行目では最大スピードを格納するフィールドを定義しています。インスタンス生成時に最大スピードを初期化し、加速するときにこのフィールドを参照して加速するかを決定します。

　7~9行目では売上金、走行距離、乗車状態のプロパティを定義しています。

　12~19行目ではコンストラクタを定義しています。このコンストラクタはガソリン量を受けとって、スーパークラスのコンストラクタを呼び出し、ガソリン量をセットしています。そのあと、ガソリンタンク容量と比較して、セットしたガソリン量が多ければ最大容量にセットするという処理をします。

　22~34行目ではSpeedUpメソッドをオーバーライドしています。抽象クラスを継承すると、抽象メソッドは必ずオーバーライドしなければならないという義務が発生します。今回は加速するときに、消費するガソリン量がない場合は加速しない、最大スピードに達していた場合はそれよりスピードが出ないようにしています。スポーツカークラスと違い、消費する燃料を抑えています。

　36~52行目では乗車する処理を定義しています。車が走っているか、既に乗車している場合には人は乗せられないようにしています。止まっているか、空車の場合は引数として受け取った料金、距離、乗車状況を、プロパティを使って設定しています。

　54~68行目では、降車する処理を定義しています。車が走っている場合は人を降ろせないようにしています。止まっていれば降車処理をしますが、今回は乗車状態を変更しています。

　次に、乗り物を運転するテストドライバークラスを作成しましょう。次にようにクラスを作成してください。

Public Class TestDriver
　'フィールド==========
　Private Accelerate As Integer　　　　　'加速度合(km)
　Private Car As Vehicle　　　　　'車
　'コンストラクタ==========
　Public Sub New(car As Vehicle, sp As Integer)
　　Me.Car = car
　　Me.Accelerate = sp
　End Sub
　'メソッド==========
　Public Sub SpeedUp()
　　Me.Car.SpeedUp(Me.Accelerate)
　End Sub
　Public Sub SpeedDown()
　　Me.Car.SpeedDown(Me.Accelerate)
　End Sub
End Class

　3行目では加速度合いを保存する変数を宣言しています。また、4行目ではテストドライバーが操作する乗り物オブジェクトを保持する変数を宣言しています。この変数はVehicle型なので、Vehcileを継承したクラスであれば保持できることになります。そのためテストドライバーは乗り物を継承した様々なタイプの乗り物を動かすことができます。今回作成したタクシークラスと、先回作成したスポーツカークラスはVehicleクラスを継承しているため、保持することができます。

　7~10行目ではコンストラクタが定義されています。引数に乗り物、加速度合いを受け取り、それぞれのフィールドにセットします。テストドライバーがどの乗り物を運転するかがテストドライバーオブジェクトを作るときに決まることになります。

　13~15行目では加速処理が定義されています。ここのSpeedUpメソッドは、乗り物クラス・スポーツカークラス・タクシークラスとは直接関係はありません。そのため、別のメソッド名で定義しても問題ありません。自分が乗っている(フィールドに保持している)乗り物のSpeedUpメソッドを呼び出す記述が14行目にあります。フィールド変数にセットされているスピード分だけ加速します。

　17~19行目では減速処理が定義されています。ここのSpeedDownメソッドは、乗り物クラス・スポーツカークラス・タクシークラスとは直接関係はありません。そのため、別のメソッド名で定義しても問題ありません。ここでの振る舞いは、前述したSpeedUpメソッドと同じです。自分が乗っている(フィールドに保持している)乗り物を減速させます。

Module Module1
　'車の状態を表示するメソッド
　Public Sub ShowMeter(car As Vehicle)
　　'コンソールの表示を消す
　　Console.Clear()
　　'各プロパティの内容を表示する
　　Console.WriteLine("スピード：{0}km/h", car.Speed)
　　Console.WriteLine("ガソリン：{0}L", car.Gas)
　End Sub
　Sub Main()
　　'選択メニューを表示
　　Console.WriteLine("走らせる車の種類を選んでください。")
　　Console.Write("1)スポーツカー　2)タクシー：")
　　Dim inputdata As String = Console.ReadLine()
　　'選択した車オブジェクトを生成
　　Dim car As Vehicle
　　Dim driver As TestDriver
　　If inputdata = 1 Then
　　　'スポーツカーとテストドライバーを生成
　　　car = New SportsCar(60)
　　　driver = New TestDriver(car, 20)
　　ElseIf inputdata = 2 Then
　　　'タクシーとテストドライバーを生成
　　　car = New Taxi(50, 60)
　　　driver = New TestDriver(car, 5)
　　Else
　　　Console.WriteLine("車を作れませんでした。")
　　　Console.ReadLine()
　　　Return
　　End If
　　'状態を表示
　　ShowMeter(car)
　　While True
　　　'操作を入力
　　　Console.Write("1)加速　2)減速　9)終了：")
　　　inputdata = Console.ReadLine()
　　　'操作によって分岐する
　　　Select Case inputdata
　　　　Case "1"
　　　　　'加速する
　　　　　driver.SpeedUp()
　　　　　ShowMeter(car)
　　　　Case "2"
　　　　　'減速する
　　　　　driver.SpeedDown()
　　　　　ShowMeter(car)
　　　　Case "9"
　　　　　'プログラムを終了する
　　　　　Return
　　　　Case Else
　　　　　ShowMeter(car)
　　　End Select
　　End While
　End Sub
End Module

　15~17 行目で、乗り物の選択肢を用意しました。ユーザーはスポーツカーかタクシーを選ぶことになります。22~34行目では、選択した乗り物と、テストドライバーを生成しています。乗り物に応じてテストドライバーに加速の仕方を指示(乗り物と加速度合い)しています。

　39~60行目では、メニューを表示してテストドライバーに加速、減速などの指示を与えています。テストドライバーは自分にセットされている乗り物に対してSpeedUpメソッドやSpeedDownメソッドを呼び出して車を走らせることになります。その状態をShowMeterメソッドで表示しています。スポーツカーかタクシーのどちらのSpeedUp・SpeedDownメソッドが呼び出されるかは、テストドライバーにどちらのオブジェクトがセットされているかによって決まります。

　抽象クラスを使用してポリモーフィズムを実現させることができました。各オブジェクトを作り、テストドライバーにテスト実行時に乗り物を指定して加速させたり減速させたりさせ、その乗り物の状態を確認してメーターに表示しています。TestDriverクラスで呼び出しているSpeedUpメソッドやSpeedDownメソッドは、どのオブジェクトがセットされるかによって振る舞いが変わっているのを確認できたと思います。これを多態性、多様性(ポリモーフィズム)と言います。

　抽象クラスでは同じような属性を持ったオブジェクトを作ることができます。乗り物クラスであれば、乗り物の部類に属するものを定義することができます。次に、属性が全く異なるものに対しても同じ処理を指定する方法を見てみましょう。