オーバーライド

　サブクラスはスーパークラスのメンバを継承することができますが、状況によってはスーパークラスの処理の内容を変更しなくてはならない場合があります。サブクラス側で同じメソッド名でかつ、同じシグネチャ(引数の構成)のメソッドを再び定義することができます。これをメソッドのオーバーライド(override)と呼びます。

　例えば、Carクラスでは、スピードの制限がありません。基本的に無限にスピードが出るように設計されています。しかし、Busではスピードの制限を設けないと危険なので、速度の制限を設けたいと思います。

Busクラスでオーバーライド
Busクラスでオーバーライド

　では、Busクラスの定義を修正してみましょう。オーバーライドするためには、スーパークラス側と、サブクラス側でオーバーライドの指定をしなくてはなりません。

■　オーバーライドされる側

Public Overridable Sub SpeedUp(sp As Integer)
　･･･
End Sub

■　オーバーライドする側

Public Overrides Sub SpeedUp(sp As Integer)
　･･･
End Sub

○　プロジェクト

プロジェクトを作成して確認してみましょう。

プロジェクトの種類 コンソール アプリケーション
プロジェクト名 OverrideTest

サンプルダウンロード

○　作成の準備

　Busクラスにメソッドを追加しましょう。「InheritanceTest」をコピーしてプロジェクトを作成してください。

○　プログラム

　まず、CarクラスのSpeedUpメソッドにvirtualキーワードを追加します。

Car.vb

  1. Public Class Car
  2. 　'フィールド==========
  3. 　'Public _speed As Integer 'スピード情報
  4. 　Private _speed As Integer 'スピード情報(修正)
  6. 　'Public _gas As Double 'ガソリン情報
  7. 　Private _gas As Double 'ガソリン情報(修正)
  1. 　'メソッド==========
  2. 　'加速させるメソッド
  3. 　Public Overridable Sub SpeedUp(sp As Integer)
  4. 　　'ガソリンを減らす
  5. 　　Me._gas -= sp / 10.0
  6. 　　If Me._gas < 0 Then 'ガソリンがマイナスになる場合
  7. 　　　'ガソリンを0に補正し、スピードを増やさない
  8. 　　　Me._gas = 0
  9. 　　Else
  10. 　　　'スピードを増やす
  11. 　　　Me._speed += sp
  12. 　　End If
  13. 　End Sub

○　解説

　42行目のメソッドの定義でOverridableキーワードを追加しました。これにより、Carクラスを継承したクラスでSpeedUpメソッドをオーバーライドできるようになります。

○　プログラム

　次に、BusクラスにSpeedUpメソッドを追加します。

Bus.vb

  1. Public Class Bus
  2. 　Inherits Car
  3. 　'プロパティ==========
  4. 　Public Property SalesAmount As Integer '運賃
  5. 　Public Property PassengerNumber As Integer '乗客人数
  7. 　'コンストラクタ==========
  8. 　Public Sub New()
  9. 　　Me.New(100)
  10. 　End Sub
  12. 　Public Sub New(gas As Double)
  13. 　　MyBase.New(gas)
  14. 　　Me.SalesAmount = 0
  15. 　　Me.PassengerNumber = 0
  16. 　End Sub
  18. 　'メソッド==========
  19. 　'乗車させるメソッド
  20. 　Public Function RideToBus(fare As Integer) As String
  21. 　　'走行中かどうか
  22. 　　If Me.Speed <> 0 Then
  23. 　　　Return "停車してください。"
  24. 　　End If
  25. 　　'満席かどうか
  26. 　　If Me.PassengerNumber >= 50 Then
  27. 　　　Return "満席のため、乗車できません。"
  28. 　　End If
  29. 　　'料金と、乗車人数を加算
  30. 　　Me.SalesAmount += fare
  31. 　　Me.PassengerNumber += 1
  32. 　　Return Nothing
  33. 　End Function
  35. 　'降車させるメソッド
  36. 　Public Function GetOffBus() As String
  37. 　　'走行中かどうか
  38. 　　If Me.Speed <> 0 Then
  39. 　　　Return "停車してください。"
  40. 　　End If
  41. 　　'乗客がいるかどうか
  42. 　　If Me.PassengerNumber = 0 Then
  43. 　　　Return "乗客はいません。"
  44. 　　End If
  45. 　　'乗車人数を減算
  46. 　　Me.PassengerNumber -= 1
  47. 　　　Return Nothing
  48. 　End Function
  50. 　'加速させるメソッド(オーバーライド)
  51. 　Public Overrides Sub SpeedUp(sp As Integer)
  52. 　　If (Me.Speed + sp) <= 60 Then
  53. 　　　MyBase.SpeedUp(sp)
  54. 　　End If
  55. 　End Sub
  56. End Class

○　クラス図

○　解説

　51~55行目でOverridesキーワードを指定してSpeedUpメソッドを再定義しています。このメソッドは加速後のスピードが60km/h以下ならスーパークラスであるCarクラスのSpeedUpメソッドを呼び出して加速しています。MyBaseキーワードはスーパークラスを指すので、MyBase.XXと指定することでスーパークラスのメンバを指定することができます。

　プログラムの修正はこれで終了です。Busクラスを利用するプログラムは修正をしませんが、60km/hまでしかスピードが出ないようになっています。これは実際のバスの運転手がバスのアクセルを踏むと自動的に60kmまでしかスピードが出なくなる状況と似ています。もしオーバーライドができないと次のようにメソッドを用意することになるかもしれません。

オーバーロードを使わないと…
オーバーロードを使わないと…

　上の図の例だとBusクラスを利用する側では「SpeedUp」と「SpeedUpForBus」というメソッドのどちらを呼び出すかを選択することになります。実際のバスの例だと、無限にスピードが出るアクセルと、60kmまでしかスピードが出ないアクセルが2つ並んでいる状態ということができます。バスの操作説明書には、「アクセルは2つありますが、必ず60㎞/hまでしかスピードが出ないアクセルを踏むようにしてください」とあったとしても、操作ミスで無限にスピードが出るアクセルを踏んでしまうかもしれませんし、スピード狂の運転手であれば、リミッターのかからない(無限にスピードが出る)アクセルをあえて踏むかもしれません。

　オーバーライドで「SpeeUp」メソッドを再定義することにより、実際のバスでアクセルは1つあるという状態を作り出すことができます。これにより、バスを安全に運用してもらうことが可能になりますし、運転手を再教育する必要はなくなるということになります。それは、使用している部品がバージョンアップしても、使い方は変わらない(プログラムを変更しなくてもよい)ということになります。

前へ   次へ