DataTable作成

　今まではDataAdapterオブジェクトを使用してデータテーブルを使ってきました。ここではデータベースと同期をとらずにDataTableオブジェクトを扱う方法を見てみましょう。次の手順でデータテーブルを生成します。

  1. DataTableオブジェクトを生成する
  2. DataTableオブジェクトに列設定を追加する
  3. DataTableオブジェクトより新規行を取得する
  4. 取得した新規行にデータを設定する
  5. 設定した行をDataTableオブジェクトに追加する

○　プロジェクト

　プロジェクトを作成して確認してみましょう。

プロジェクトの種類 コンソール アプリケーション
プロジェクト名 DataTableCreateTest

サンプルダウンロード

○　プログラム

　Mainメソッドを次のように修正してください。

Module1.vb

  1. Sub Main()
  2. 　'DataTableオブジェクトを生成
  3. 　Dim dt As New DataTable("Personal")
  5. 　'DataTableオブジェクトに列を追加
  6. 　dt.Columns.Add("last_name", Type.GetType("System.String"))
  7. 　dt.Columns.Add("first_name", Type.GetType("System.String"))
  8. 　dt.Columns.Add("age", Type.GetType("System.Int32"))
  10. 　'ループ
  11. 　While True
  12. 　　'メニューを表示
  13. 　　Console.WriteLine("次のメニューから選んでください。")
  14. 　　Console.Write("1)追加　　2)一覧　　9)終了：")
  15. 　　Dim menunum As String = Console.ReadLine()
  17. 　　'メニューに応じて処理を分岐
  18. 　　Select Case menunum
  19. 　　　Case "1"
  20. 　　　　'データを入力
  21. 　　　　Console.Write("姓：")
  22. 　　　　Dim lname As String = Console.ReadLine()
  23. 　　　　Console.Write("名：")
  24. 　　　　Dim fname As String = Console.ReadLine()
  25. 　　　　Console.Write("年齢：")
  26. 　　　　Dim age As Integer
  27. 　　　　Try
  28. 　　　　　age = Int32.Parse(Console.ReadLine())
  29. 　　　　Catch ex As Exception
  30. 　　　　　Console.WriteLine("年齢は数字を入力してください。")
  31. 　　　　　Exit Select
  32. 　　　　End Try
  34. 　　　　'DataTableオブジェクトより新規行を取得
  35. 　　　　Dim dr As DataRow = dt.NewRow()
  37. 　　　　'取得した行にデータを設定
  38. 　　　　dr("last_name") = lname
  39. 　　　　dr("first_name") = fname
  40. 　　　　dr("age") = age
  42. 　　　　'新規行をDataTableオブジェクトに追加
  43. 　　　　dt.Rows.Add(dr)
  44. 　　　Case "2"
  45. 　　　　'表示するデータがない場合
  46. 　　　　If dt.Rows.Count = 0 Then
  47. 　　　　　Console.WriteLine("表示するデータはありません。")
  48. 　　　　　Exit Select
  49. 　　　　End If
  51. 　　　　'DataTableオブジェクトの行を表示
  52. 　　　　Console.WriteLine("姓" & vbTab & "名" & vbTab & "年齢")
  53. 　　　　For Each dtrow As DataRow In dt.Rows
  54. 　　　　　Console.WriteLine("{0}" & vbTab & "{1}" & vbTab & "{2}", dtrow("last_name"), dtrow("first_name"), dtrow("age"))
  55. 　　　　Next
  56. 　　　Case "9"
  57. 　　　　Return
  58. 　　　Case Else
  59. 　　　　Console.WriteLine("正しい番号を入力してください。")
  60. 　　End Select
  61. 　　Console.WriteLine()
  62. 　End While
  63. End Sub

○　実行結果

次のメニューから選んでください。
1)追加　　2)一覧　　9)終了：2
表示するデータはありません。

次のメニューから選んでください。
1)追加　　2)一覧　　9)終了：1
姓：佐藤
名：一郎
年齢：22

次のメニューから選んでください。
1)追加　　2)一覧　　9)終了：2
姓 名 年齢
佐藤 一郎 22

次のメニューから選んでください。
1)追加　　2)一覧　　9)終了：1
姓：鈴木
名：花子
年齢：a
年齢は数字を入力してください。

次のメニューから選んでください。
1)追加　　2)一覧　　9)終了：1
姓：鈴木
名：花子
年齢：33

次のメニューから選んでください。
1)追加　　2)一覧　　9)終了：2
姓 名 年齢
佐藤 一郎 22
鈴木 花子 33

次のメニューから選んでください。
1)追加　　2)一覧　　9)終了：9
(終了)

○　解説

　5行目では、DataTableオブジェクトを生成しています。そして8～10行目では列情報を追加しています。ColumnsコレクションンのAddメソッドに列名と、データ型を指定しています。今回は、姓・名・年齢を保存する列を定義しています。

　37行目ではデータを追加するために10行目までで準備したDataTableオブジェクトのNewRowメソッドを使ってDataRowオブジェクトを取得しています。このオブジェクトは行を表すオブジェクトで、姓・名・年齢を格納することができます。40~42行目で各列に入力したデータを設定しています。

　55～57行目では、DataTableオブジェクトの行数だけループします。56行目では取り出した1行のデータを表示しています。

前へ   次へ