カプセル化

　今まで作成したサンプルは、危険が潜んでいます。それは、スピードやガソリン残量を直接指定することができるという点です。急発進や、急停車、走行中にもかかわらず、ガソリン残量を変更できてしまいます。このままでは、完成されたオブジェクトとは言えません。

フィールドに自由にアクセスできる
フィールドに自由にアクセスできる

　そこで、オブジェクト指向の特徴のひとつである「カプセル化」を使用して、安全なクラスを作成しましょう。クラスを定義する際に、アクセス修飾子を指定することにより、カプセル化を行うことができます。アクセス修飾子は以下のような指定ができます。

アクセス修飾子 意味
Public クラスの内部・外部問わず、自由にアクセスすることができます。アクセス制限のレベルが最も低い修飾子です。
Protected クラスの内部と、派生したクラスからはアクセスすることができます。
Friend 同一プログラム内からであれば、自由にアクセスすることができます。
Protected Friend ProtectedとFriendを合わせたアクセス修飾子です。
Private クラスの内部からしかアクセスすることができません。アクセス制限のレベルが最も高い修飾子です。
アクセス修飾子一覧

○　プロジェクト

　プロジェクトを作成して確認してみましょう。

プロジェクトの種類 コンソール アプリケーション
プロジェクト名 CapsuleTest

サンプルダウンロード

○　作成の準備

　「InstanceTest」プロジェクトを修正して作成しましょう。IntsantTestソリューションフォルダーのコピーを作り、フォルダー名をプロジェクト名に変更してください。コピーしてフォルダー名を変更したフォルダーからソリューションファイルを開いてVisual Studioを起動してください。起動するとプロジェクト名は変わっていませんが、複製を編集することになります。

○　プログラム

　Carクラスのフィールドを外部から直接操作できないようにしましょう。次のようにプログラムを変更してください。

Car.vb

  1. Public Class Car
  2. 　'フィールド==========
  3. 　'Public _speed As Integer　　　　　'スピード情報
  4. 　Private _speed As Integer　　　　　'スピード情報(修正)
  6. 　'Public _gas As Double　　　　　'ガソリン情報
  7. 　Private _gas As Double　　　　　'ガソリン情報(修正)
  9. 　'メソッド==========
  10. 　'加速させるメソッド
  11. 　Public Sub SpeedUp(sp As Integer)
  12. 　　'ガソリンを減らす
  13. 　　Me._gas -= sp / 10.0
  14. 　　If Me._gas < 0 Then　　　　　'ガソリンがマイナスになる場合
  15. 　　　'ガソリンを0に補正し、スピードを増やさない
  16. 　　　Me._gas = 0
  17. 　　Else
  18. 　　　'スピードを増やす
  19. 　　　Me._speed += sp
  20. 　　End If
  21. 　End Sub
  23. 　'減速させるメソッド
  24. 　Public Sub SpeedDown(sp As Integer)
  25. 　　'スピードを減らす
  26. 　　Me._speed -= sp
  27. 　　If Me._speed < 0 Then　　　　　'スピードがマイナスになる場合
  28. 　　　'スピードを0に補正する
  29. 　　　Me._speed = 0
  30. 　　End If
  31. 　End Sub
  32. End Class

○　クラス図

○　解説

　3行目と6行目のフィールド変数のアクセス修飾子は「Public」を指定していたため、外部のクラスから直接アクセスできました。今回は、カプセル化をするために一旦これらの行をコメントアウトしてプログラムから外しています。4行目と7行目でアクセス修飾子を「Private」に変更することにより、外部のクラスからアクセスすることができなくなります。

カプセル化によりアクセスできなくなる
カプセル化によりアクセスできなくなる

　すると、このクラスを利用する記述の部分で変化が生じます。フィールドに値を代入したり、参照したりする記述ができなくなります。そのため、必要であればメソッドとして値を代入したり、参照したりする機能を追加しなくてはなりません。

○　プログラム

　次のようにCarクラスにメソッドを追加してください。

Car.vb

  1. Public Class Car
  2. 　'フィールド==========
  3. 　'Public _speed As Integer　　　　　'スピード情報
  4. 　Private _speed As Integer　　　　　'スピード情報(修正)
  6. 　'Public _gas As Double　　　　　'ガソリン情報
  7. 　Private _gas As Double　　　　　'ガソリン情報(修正)
  9. 　'メソッド==========
  10. 　'加速させるメソッド
  11. 　Public Sub SpeedUp(sp As Integer)
  12. 　　'ガソリンを減らす
  13. 　　Me._gas -= sp / 10.0
  14. 　　If Me._gas < 0 Then　　　　　'ガソリンがマイナスになる場合
  15. 　　　'ガソリンを0に補正し、スピードを増やさない
  16. 　　　Me._gas = 0
  17. 　　Else
  18. 　　　'スピードを増やす
  19. 　　　Me._speed += sp
  20. 　　End If
  21. 　End Sub
  23. 　'減速させるメソッド
  24. 　Public Sub SpeedDown(sp As Integer)
  25. 　　'スピードを減らす
  26. 　　Me._speed -= sp
  27. 　　If Me._speed < 0 Then　　　　　'スピードがマイナスになる場合
  28. 　　　'スピードを0に補正する
  29. 　　　Me._speed = 0
  30. 　　End If
  31. 　End Sub
  33. 　'初期化を行うメソッド
  34. 　Public Sub Init(gas As Double)
  35. 　　Me._speed = 0
  36. 　　Me._gas = gas
  37. 　End Sub
  39. 　'スピードを取得する
  40. 　Public Function GetSpeed() As Integer
  41. 　　Return Me._speed
  42. 　End Function
  44. 　'ガソリン量を取得する
  45. 　Public Function GetGas() As Double
  46. 　　Return Me._gas
  47. 　End Function
  49. End Class

○　クラス図

○　解説

　Carクラスを利用するクラスからフィールド変数に代入することで初期化をしていましたが、カプセル化によりフィールド変数にアクセスできなくなったために、34~37行目ではフィールド変数を初期化する手続きを用意しました。引数にガソリン量を受け取り、スピード情報を「0km」に、ガソリン量を引数のデータで初期化しています。

　また、Carクラスを利用するクラスからフィールド変数を直接参照してスピード情報やガソリン量を取得していましたが、カプセル化によりフィールド変数にアクセスできなくなったために、40~42行目ではスピードを戻り値として返す手続きを、45~47行目ではガソリン量を戻り値として返す手続きを用意しました。

○　プログラム

　では、Carオブジェクトを生成して利用しているプログラムも修正しましょう。

Module1.vb

  1. Module Module1
  3. 　'車の状態を表示するメソッド
  4. 　Sub ShowData(c As Car)
  5. 　　'Console.WriteLine("スピード：{0}km", c._speed)
  6. 　　Console.WriteLine("スピード：{0}km", c.GetSpeed())
  7. 　　'Console.WriteLine("ガソリン：{0}L", c._gas)
  8. 　　Console.WriteLine("ガソリン：{0}L", c.GetGas())
  9. 　End Sub
  11. 　Sub Main()
  12. 　　'インスタンスを生成する
  13. 　　Dim obj As New Car()
  15. 　　'フィールド変数を初期化する
  16. 　　'obj._speed = 0
  17. 　　'obj._gas = 20.0
  18. 　　obj.Init(20)
  20. 　　'現在の状態を表示する
  21. 　　ShowData(obj)
  23. 　　While True
  24. 　　　'操作を入力
  25. 　　　Console.Write("1)加速　2)減速　9)終了：")
  26. 　　　Dim inputdata As String = Console.ReadLine()
  28. 　　　'操作によって分岐する
  29. 　　　Select Case inputdata
  30. 　　　　Case "1"
  31. 　　　　　'加速する
  32. 　　　　　obj.SpeedUp(5)
  33. 　　　　　ShowData(obj)
  34. 　　　　Case "2"
  35. 　　　　　'減速する
  36. 　　　　　obj.SpeedDown(5)
  37. 　　　　　ShowData(obj)
  38. 　　　　Case "9"
  39. 　　　　　'プログラムを終了する
  40. 　　　　　Return
  41. 　　　End Select
  42. 　　End While
  44. 　End Sub
  46. End Module

○　解説

　5、7行目では、Carクラスのカプセル化によりフィールド変数にアクセスできなくなったためにエラーとなります。そのため、コメントアウトしています。その代わりに6、8行目で新たに手続きとして用意されたスピードやガソリン量を取得するメソッドを呼び出しています。

　16、17行目では、Carクラスのカプセル化によりフィールド変数にアクセスできなくなったためにエラーとなります。そのため、コメントアウトしています。その代わりに18行目で新たに手続きとして用意された初期化を行なうメソッドを呼び出しています。

　このようにカプセル化をすることにより、クラスの利用者側から直接データを参照・設定できなくすることにより、クラス作成者の意図に沿わない方法で使用されるのを避けることができます。手続きを用意することによって必要な処理をさせることができます。また、クラスを利用する側も特に意識することなく安全に、クラスを利用することができるようになります。

カプセル化したフィールドにアクセスするメソッドを用意
カプセル化したフィールドにアクセスするメソッドを用意

　一般的に、フィールドはPrivate指定で非公開にして、メソッドをPublicで公開にします。ただし、内部処理などで使うメソッドはPrivateにして、外部から利用されないようにします。

前へ   次へ