プロパティ

　VBでは、クラスの中にプロパティを定義することができます。このプロパティは、クラス作成者の側から見ると、メソッドのように記述をします。クラス利用者の側から見ると、フィールドのように利用できます。

プロパティのイメージ
プロパティのイメージ

プロパティ定義の書式
アクセス修飾子 Property プロパティ名 As データ型
　Get
　　フィールド取得の記述
　End Get
　Set(value As データ型)
　　フィールド設定の記述
　End Set
End Property

　アクセス修飾子ではPublicやPrivateのほかに、「ReadOnly」「WriteOnly」を指定することにより、代入するか、参照するかの制限を指定することができます。

　次のプログラムは「ReadOnly」を指定したプログラムです。Getプロシージャのみ表示されます。

Public ReadOnly Property Speed As Integer
　Get

　End Get
End Property

　次のプログラムは「WriteOnly」を指定したプログラムです。Setプロシージャのみ表示されます。

　
Public WriteOnly Property Speed As Integer
　Set(value As Integer)

　End Set
End Property

　また、プロパティを省略して書くこともできます。

例：

Public Property Speed As Integer
　Get
　　Return Me._speed
　End Get
　Set(value As Integer)　　　　　　　　　　⇒　　　　　　　　　　Public Property Speed() As Integer
　　Me._speed = value
　End Set
End Property

○　プロジェクト

　プロジェクトを作成して確認してみましょう。

プロジェクトの種類 コンソール アプリケーション
プロジェクト名 PropertyTest

サンプルダウンロード

○　作成の準備

　Carクラスにプロパティを追加しましょう。「ConstractorTest」をコピーしてプロジェクトを作成してください。

○　プログラム

　次のように記述を追加・修正してください。

Car.vb

  1. Public Class Car
  2. 　'フィールド==========
  3. 　'Public _speed As Integer 'スピード情報
  4. 　Private _speed As Integer 'スピード情報(修正)
  6. 　'Public _gas As Double 'ガソリン情報
  7. 　Private _gas As Double 'ガソリン情報(修正)
  9. 　'プロパティ==========
  10. 　'スピード参照用
  11. 　Public ReadOnly Property Speed As Integer
  12. 　　Get
  13. 　　　Return Me._speed
  14. 　　End Get
  15. 　End Property
  17. 　'ガソリン参照・設定用
  18. 　Public Property Gas As Double
  19. 　　Get
  20. 　　　Return Me._gas
  21. 　　End Get
  22. 　　Set(value As Double)
  23. 　　　'止まっている場合は指定したガソリン量を給油
  24. 　　　If Me._speed = 0 Then
  25. 　　　　Me._gas += value
  26. 　　　End If
  27. 　　End Set
  28. 　End Property
  30. 　'コンストラクタ===========
  31. 　Public Sub New()
  32. 　　Me.New(20)
  33. 　End Sub
(そのほかの記述…)
  1. 　'初期化を行うメソッド
  2. 　'Public Sub Init(gas As Double)
  3. 　' Me._speed = 0
  4. 　' Me._gas = gas
  5. 　'End Sub
  7. 　''スピードを取得する
  8. 　'Public Function GetSpeed() As Integer
  9. 　' Return Me._speed
  10. 　'End Function
  12. 　''ガソリン量を取得する
  13. 　'Public Function GetGas() As Double
  14. 　' Return Me._gas
  15. 　'End Function
  17. 　''ガソリンを給油するメソッド
  18. 　'Public Sub SetGas()
  19. 　' 'オーバーロードしているメソッドを呼び出す
  20. 　' Me.SetGas(20)
  21. 　'End Sub
  23. 　'Public Sub SetGas(gas As Double)
  24. 　' '止まっている場合は指定したガソリン量を給油
  25. 　' If Me._speed = 0 Then
  26. 　' Me._gas += gas
  27. 　' End If
  28. 　'End Sub
  30. End Class

○　クラス図

○　解説

　11~15行目では、スピード参照用のプロパティを定義しています。利用するプログラム側で「オブジェクト変数名.Speed」と記述することにより、Getプロシージャで記述されている処理を実行します。今回は、_speedフィールド変数の内容を返します。

　18~28行目では、ガソリン量の参照・設定用のプロパティを定義しています。利用するプログラム側で「オブジェクト変数名.Gas」と記述することにより、Getプロシージャで記述されている処理を実行します。今回は、_gasフィールド変数の内容を返します。また利用するプログラム側で「オブジェクト変数名.Gas = 30.5」と記述することにより、Setプロシージャで記述されている処理を実行します。代入されたデータはvalueキーワードで扱えるので、車が止まっている場合は_gasフィールド変数に設定するガソリン量を加算します。

　スピード参照、ガソリン量参照・設定のプロパティを用意したので、同じような処理をするメソッドはコメントアウトして廃止しました。

○　プログラム

　プロパティが用意されたので、Carクラスを利用する記述も変更しましょう。

Module1.vb

  1. Module Module1
  3. 　'車の状態を表示するメソッド
  4. 　Sub ShowData(c As Car)
  5. 　　'Console.WriteLine("スピード：{0}km", c._speed)
  6. 　　'Console.WriteLine("スピード：{0}km", c.GetSpeed())
  7. 　　Console.WriteLine("スピード：{0}km", c.Speed)
  8. 　　'Console.WriteLine("ガソリン：{0}L", c._gas)
  9. 　　'Console.WriteLine("ガソリン：{0}L", c.GetGas())
  10. 　　Console.WriteLine("ガソリン：{0}L", c.Gas)
  11. 　End Sub
  13. 　Sub Main()
  14. 　　'インスタンスを生成する
  15. 　　Dim obj As New Car(40)
  17. 　　'フィールド変数を初期化する
  18. 　　'obj._speed = 0
  19. 　　'obj._gas = 20.0
  20. 　　'obj.Init(20)
  22. 　　'現在の状態を表示する
  23. 　　ShowData(obj)
  25. 　　While True
  26. 　　　'操作を入力
  27. 　　　Console.Write("1)加速　2)減速　3)給油　9)終了：")
  28. 　　　Dim inputdata As String = Console.ReadLine()
  30. 　　　'操作によって分岐する
  31. 　　　Select Case inputdata
  32. 　　　　Case "1"
  33. 　　　　　'加速する
  34. 　　　　　obj.SpeedUp(5)
  35. 　　　　　ShowData(obj)
  36. 　　　　Case "2"
  37. 　　　　　'減速する
  38. 　　　　　obj.SpeedDown(5)
  39. 　　　　　ShowData(obj)
  40. 　　　　Case "3"
  41. 　　　　　'給油する
  42. 　　　　　'obj.SetGas(35)
  43. 　　　　　obj.Gas = 35
  44. 　　　　　ShowData(obj)
  45. 　　　　Case "9"
  46. 　　　　　'プログラムを終了する
  47. 　　　　　Return
  48. 　　　End Select
  49. 　　End While
  50. 　End Sub
  52. End Module

○　解説

　6、9、43行目は、メソッドの廃止により使えなくなったのでコメントアウトしました。その代わりに用意されたプロパティを利用するために、7、10行目はプロパティの参照の記述をしています。また、44行目でもメソッドによってガソリン量を設定していましたが、プロパティの代入によってガソリン量を設定する記述を追加しました。

　このようにプロパティを追加することにより、Carオブジェクトにとってはメソッドのように動作し、Carクラスを利用するオブジェクトからはフィールドを使うかのように利用することができるようになりました。

　また、プロパティを定義することでフィールドの定義を省略することができます。

○　プロジェクト

　プロジェクトを作成して確認してみましょう。

プロジェクトの種類 コンソール アプリケーション
プロジェクト名 PropertyTest2

サンプルダウンロード

○　プログラム

　Fruitクラスを追加して次のように定義してください。

Fruit.vb

  1. Public Class Fruit
  2. 　'プロパティ
  3. 　Public Property Name As String
  4. 　Public Property Price As Integer
  6. 　'コンストラクタ
  7. 　Public Sub New(name As String)
  8. 　　Me.New(name, 0)
  9. 　End Sub
  11. 　Public Sub New(name As String, price As Integer)
  12. 　　Me.Name = name
  13. 　　Me.Price = price
  14. 　End Sub
  16. 　'メソッド
  17. 　'個数を受け取って合計金額を計算するメソッド
  18. 　Public Function CalculatePrice(quantity As Integer) As Integer
  19. 　　Return Me.Price * quantity
  20. 　End Function
  21. End Class

○　クラス図

○　解説

　今回のサンプルでのFruitクラスは、名前と価格の情報を持ち、個数を指定すると価格を元に合計金額を計算するメソッドを定義しています。

　3、4行目ではプロパティを定義しています。フィールドは定義していません。このようにプロパティのみ定義することでそれに対応するフィールドは自動的に用意されます。フィールドに対する参照や設定が単純なものは今回のように自動実装のプロパティで用意することができます。

○　プログラム

　Fruitクラスを利用するプログラムを記述してください。

Module1.vb

  1. Module Module1
  3. 　Sub Main()
  4. 　　'フルーツオブジェクト生成
  5. 　　Dim fruitobj As New Fruit("りんご", 150)
  7. 　　'りんごの合計金額を取得
  8. 　　Dim totalprice As Integer = fruitobj.CalculatePrice(5)
  10. 　　'りんごの合計金額を表示
  11. 　　Console.WriteLine("商品名：{0}", fruitobj.Name)
  12. 　　Console.WriteLine("合計金額：{0}円", totalprice)
  13. 　　Console.ReadLine()
  14. 　End Sub
  16. End Module

○　解説

　Fruitオブジェクトを生成して利用しています。11行目でプロパティを参照しています。5行目のコンストラクタで商品名を指定した内容が取得されます。

○　実行結果

商品名：りんご
合計金額：750円

前へ   次へ