コンストラクタ

　今まで作成したCarクラスは、オブジェクトを生成後に初期化して使用してもらいました。もし、初期化せずに使用するとどうなるのでしょうか？ガソリンが0リッターなので、加速しても走りません。Carクラスには初期化メソッドが用意されており、Carクラスを利用する側が呼び出しの記述をしないと初期化されません。そこで、オブジェクトを生成した時に初期化をするように調整しましょう。そのようなときに利用できる仕組みが「コンストラクタ」です。

　コンストラクタは、クラスからインスタンス生成をする際にフィールド変数に値を設定するなどの初期設定を行う機能です。インスタンス生成を行う際に呼び出される特別なメソッドを記述します。

コンストラクタ定義の書式
アクセス修飾子 Sub New(仮引数リスト)
　フィールドの初期化処理など
End Sub

○　プロジェクト

　プロジェクトを作成して確認してみましょう。

プロジェクトの種類 コンソール アプリケーション
プロジェクト名 ConstractorTest

サンプルダウンロード

○　作成の準備

　Carクラスにコンストラクタの記述を追加しましょう。「OverloadTest」をコピーしてプロジェクトを作成してください。

○　プログラム

　次のように記述を追加・修正してください。

Car.vb

  1. Public Class Car
  2. 　'フィールド==========
  3. 　'Public _speed As Integer　　　　　'スピード情報
  4. 　Private _speed As Integer　　　　　'スピード情報(修正)
  6. 　'Public _gas As Double　　　　　　'ガソリン情報
  7. 　Private _gas As Double　　　　　'ガソリン情報(修正)
  9. 　'コンストラクタ===========
  10. 　Public Sub New()
  11. 　　Me.New(20)
  12. 　End Sub
  14. 　Public Sub New(gas As Double)
  15. 　　Me._speed = 0
  16. 　　Me._gas = gas
  17. 　End Sub
  19. 　'メソッド==========
  20. 　'加速させるメソッド
  21. 　Public Sub SpeedUp(sp As Integer)
  22. 　　'ガソリンを減らす
  23. 　　Me._gas -= sp / 10.0
  24. 　　If Me._gas < 0 Then 'ガソリンがマイナスになる場合
  25. 　　　'ガソリンを0に補正し、スピードを増やさない
  26. 　　　Me._gas = 0
  27. 　　Else
  28. 　　　'スピードを増やす
  29. 　　　Me._speed += sp
  30. 　　End If
  31. 　End Sub
  33. 　'減速させるメソッド
  34. 　Public Sub SpeedDown(sp As Integer)
  35. 　　'スピードを減らす
  36. 　　Me._speed -= sp
  37. 　　If Me._speed < 0 Then　　　　　'スピードがマイナスになる場合
  38. 　　　'スピードを0に補正する
  39. 　　　Me._speed = 0
  40. 　　End If
  41. 　End Sub
  43. 　'初期化を行うメソッド
  44. 　'Public Sub Init(gas As Double)
  45. 　' Me._speed = 0
  46. 　' Me._gas = gas
  47. 　'End Sub
  49. 　'スピードを取得する
  50. 　Public Function GetSpeed() As Integer
  51. 　　Return Me._speed
  52. 　End Function
    53. (そのほかの記述…)

○　クラス図

○　解説

　10~12行目でコンストラクタを定義しています。このコンストラクタは引数を受け取らず、呼び出されたらもう一つの引数を受け取るコンストラクタにガソリン量を表す「20」を渡して呼び出しています。

　14~17行目では引数を受け付けるコンストラクタを定義しています。スピード情報に「０」をセットし、ガソリン量を引数で受け取ったデータでセットします。

　44~47行目では、コンストラクタを定義することにより初期化を行うメソッドが不要になったので、コメントアウト(削除)しています。

○　プログラム

　コンストラクタが用意されたので、インスタンスを生成する記述も変更しましょう。

Module1.vb

  1. Sub Main()
  2. 　'インスタンスを生成する
  3. 　Dim obj As New Car(40)
  5. 　'フィールド変数を初期化する
  6. 　'obj._speed = 0
  7. 　'obj._gas = 20.0
  8. 　'obj.Init(20)
  10. 　'現在の状態を表示する
  11. 　ShowData(obj)
  13. 　While True
  14. 　　'操作を入力
  15. 　　Console.Write("1)加速　2)減速　3)給油　9)終了：")
  16. 　　Dim inputdata As String = Console.ReadLine()
  18. 　　'操作によって分岐する
  19. 　　Select Case inputdata
  20. 　　　Case "1"
  21. 　　　　'加速する
  22. 　　　　obj.SpeedUp(5)
  23. 　　　　ShowData(obj)
  24. 　　　Case "2"
  25. 　　　　'減速する
  26. 　　　　obj.SpeedDown(5)
  27. 　　　　ShowData(obj)
  28. 　　　Case "3"
  29. 　　　　'給油する
  30. 　　　　obj.SetGas(35)
  31. 　　　　ShowData(obj)
  32. 　　　Case "9"
  33. 　　　　'プログラムを終了する
  34. 　　　　Return
  35. 　　End Select
  36. 　End While
  37. End Sub

○　解説

　18行目で、フィールドを初期化するメソッドの呼び出しは廃止されたため、コメントアウトして実行させないようにしました。その代わりに用意されたコンストラクタで初期化をするために13行目では、インスタンス生成時の引数にガソリン量のデータを渡しています。

　前節まではコンストラクタを定義していませんでした。しかし、インスタンス生成時に「New Car()」としていました。コンストラクタを定義していない場合は、引数なし・処理なしのコンストラクタが仮定されて、インスタンスが生成されます。なお、引数を持たないコンストラクタのことを「デフォルトコンストラクタ」と呼びます。

デフォルトコンストラクタのイメージ
デフォルトコンストラクタのイメージ

　今回のように引数を持つコンストラクタが1つでも定義されている場合は、デフォルトコンストラクタは仮定されません。デフォルトコンストラクタを使用したい場合は引数を持たないコンストラクタを明示的に定義しなくてはなりません。

デフォルトコンストラクタは仮定されない
デフォルトコンストラクタは仮定されない

　なお、コンストラクタもオーバーロードさせることができます。コンストラクタ内で同じクラスにある別のコンストラクタを呼ぶ場合は「Car.vb」の11行目にあるように、コンストラクタの定義の最初の行に「 Me.New()」のように記述をします。

前へ   次へ