継承

　継承は、インヘリタンスとも呼ばれます。既に用意されているオブジェクトを基に、機能などを追加して新たなオブジェクトを作ることができる機能です。

　これから、Busクラスを作成してみましょう。バスは、人を乗せて運ぶことができますが、車と同じように進んだり、止まったりすることができます。つまり、Carクラスのような機能を持っています。「バスは車である」ということができます。このような関係を「is-a」の関係といいます(Bus is a Car)。

　このような場合、BusクラスはCarクラスの機能等を引き継いで作成することができます。Carクラスを継承してBusクラスを作ることができます。このようにすることで、Busにしかない属性、機能を記述すればよくなります。つまり、CarクラスとBusクラスの差分を記述するわけです。

　継承において、もとになるクラスをスーパークラスや基底クラスといい、それをもとに新しく作成するクラスをサブクラスや派生クラスといいます。

　継承の指定をした後、スーパークラスにはないフィールドやメソッドを追加や修正する記述をします。

　Busクラスを作成しましょう。「PropertyTest」をコピーしてプロジェクトを作成してください。

クラス継承の書式
Class サブクラス名　Inherits スーパークラス名　各種定義… End Class

プロジェクトの種類	コンソールアプリケーション
プロジェクト名	InheritanceTest

Public Class Bus
　Inherits Car
　'プロパティ==========
　Public Property SalesAmount As Integer '運賃
　Public Property PassengerNumber As Integer '乗客人数
　'コンストラクタ==========
　Public Sub New()
　　Me.New(100)
　End Sub
　Public Sub New(gas As Double)
　　MyBase.New(gas)
　　Me.SalesAmount = 0
　　Me.PassengerNumber = 0
　End Sub
　'メソッド==========
　'乗車させるメソッド
　Public Function RideToBus(fare As Integer) As String
　　'走行中かどうか
　　If Me.Speed <> 0 Then
　　　Return "停車してください。"
　　End If
　　'満席かどうか
　　If Me.PassengerNumber >= 50 Then
　　　Return "満席のため、乗車できません。"
　　End If
　　'料金と、乗車人数を加算
　　Me.SalesAmount += fare
　　Me.PassengerNumber += 1
　　Return Nothing
　End Function
　'降車させるメソッド
　Public Function GetOffBus() As String
　　'走行中かどうか
　　If Me.Speed <> 0 Then
　　　Return "停車してください。"
　　End If
　　'乗客がいるかどうか
　　If Me.PassengerNumber = 0 Then
　　　Return "乗客はいません。"
　　End If
　　'乗車人数を減算
　　Me.PassengerNumber -= 1
　　Return Nothing
　End Function
End Class

　2行目でCarクラスを継承しています。これにより、Carクラスが持っているSpeedUpメソッド、SpeedDownメソッドが使えるようになります。

　4行目のプロパティは売上金額を扱います。乗客が乗車するたびに加算されていきます。5行目のプロパティは現在の乗客数を扱います。今回は50人まで乗せられるようにプログラムで制御しています。

　8~10行目ではコンストラクタを定義しています。このコンストラクタは引数なしで呼ばれると、オーバーロードしているガソリン量を受け取るコンストラクタを呼び出します。12~16行目では、ガソリン量を受け取るコンストラクタを定義しています。13行目はスーパークラスのコンストラクタを呼び出しています。「MyBase」キーワードは、スーパークラスを表します。ここでのMyBaseキーワードはCarクラスを表します。

　20~33行目は乗車するメソッドです。このメソッドは運賃を受け取り、乗車処理をします。その際、バスが走っていたり、乗客数が満員になっていたりすると乗車できないようにしています。いずれにも当てはまらない場合は、受け取った運賃を売上金額プロパティに加算し、乗客数プロパティを1人分増やします。

　36~48行目は降車するメソッドです。バスが走っていたり、乗客がいない場合は降車できないようにしています。いずれにも当てはまらない場合は、乗客数プロパティを1人分減らします。　

　Busクラスを利用するプログラムを作成しましょう。次のように変更してください。

Module Module1
　'車の状態を表示するメソッド
　Sub ShowData(c As Bus)
　　Console.WriteLine("スピード：{0}km", c.Speed)
　　Console.WriteLine("ガソリン：{0}L", c.Gas)
　　Console.WriteLine("売上金額：{0}円", c.SalesAmount)
　　Console.WriteLine("乗車人数：{0}人", c.PassengerNumber)
　End Sub
　Sub Main()
　　'インスタンスを生成する
　　Dim obj As New Bus(150)
　　'現在の状態を表示する
　　ShowData(obj)
　　While True
　　　'操作を入力
　　　Console.Write("1)加速　2)減速　3)給油　7)乗車　8)降車　9)終了：")
　　　Dim inputdata As String = Console.ReadLine()
　　　'操作によって分岐する
　　　Select Case inputdata
　　　　Case "1"
　　　　　'加速する
　　　　　obj.SpeedUp(5)
　　　　　ShowData(obj)
　　　　Case "2"
　　　　　'減速する
　　　　　obj.SpeedDown(5)
　　　　　ShowData(obj)
　　　　Case "3"
　　　　　'給油する
　　　　　'obj.SetGas(35)
　　　　　obj.Gas = 80
　　　　　ShowData(obj)
　　　　Case "7"
　　　　　'乗車する
　　　　　Dim retride As String = obj.RideToBus(200)
　　　　　If retride Is Nothing Then
　　　　　　ShowData(obj)
　　　　　Else
　　　　　　Console.WriteLine(retride)
　　　　　End If
　　　　Case "8"
　　　　　Dim retgetoff As String = obj.GetOffBus()
　　　　　If retgetoff Is Nothing Then
　　　　　　ShowData(obj)
　　　　　Else
　　　　　　Console.WriteLine(retgetoff)
　　　　　End If
　　　　Case "9"
　　　　　'プログラムを終了する
　　　　　Return
　　　End Select
　　End While
　End Sub
End Module

　13行目でBusオブジェクトを生成しています。BusオブジェクトはCarクラスを継承しているので今まで通り加速したり、減速したりできます。40行目では乗車メソッドを呼び出しています。戻り値がNothingでない場合はエラーメッセージが返って来ているので、コンソールに表示しています。47行目では降車メソッドを呼び出しています。このメソッドは乗車メソッドと同様にエラーメッセージかNothingが返ってくるのでそれに応じた処理をしています。

　今回はCarクラスを基にBusクラスを作成しました。BusクラスはCarクラスを継承しているので、Carクラスのメンバを記述しなくても使用することができます。ただし、Privateになっているメンバは、継承したクラスでも直接アクセスすることができません。「Protected」にすれば、直接操作できます。「Protected」は、継承関係であればアクセスできますが、外部クラスからはアクセスすることができません。

　VBでは、サブクラスは1つのクラスから継承することができます。複数のクラスから継承させることはできません。（多重継承の禁止）

　Busクラスのインスタンスを生成するときにBusクラスのコンストラクタを呼び出します。すると、初めにスーパークラスであるCarクラスのコンストラクタを呼び出します。サブクラスのコンストラクタでスーパークラスのコンストラクタの呼び出しが特に記述されていない場合、スーパークラスのデフォルトコンストラクタが呼び出されます。もし、スーパークラスで引数を持つコンストラクタが定義されていると、デフォルトコンストラクタは仮定されないので、サブクラスでスーパークラスのコンストラクタの呼び出しを記述しなければなりません。