抽象クラス

　ポリモーフィズムを実現させるにはいくつかの方法があります。ここでは、抽象クラスについてみてみましょう。抽象クラスは、抽象メソッドを含むクラスです。抽象メソッドとは、処理を定義していないメソッド、つまり、メソッド名、引数リスト、戻り値の型のみ宣言されているメソッドです。抽象メソッドは「MustOverride」キーワードをつけて宣言します。

抽象メソッド定義の書式
アクセス修飾子 MustOverride Sub メソッド名(引数リスト)

アクセス修飾子 MustOverride Function メソッド名(引数リスト) As 戻り値の型

　抽象メソッドを持つクラスは具現化しないと使えないため、クラスに「MustInherit」キーワードをつける必要があります。それにより、抽象クラスとします。

抽象クラス定義の書式
アクセス修飾子 MustInherit Class クラス名
　各種定義…
End Class

　抽象クラスはインスタンスを生成できません。別のクラスで継承し、抽象メソッドをオーバーライドして利用することができるようになります。

○　プロジェクト

　プロジェクトを作成して確認してみましょう。

プロジェクトの種類 コンソール アプリケーション
プロジェクト名 AbstructClassTest

サンプルダウンロード

○　プログラム

　抽象クラスを作成しましょう。今回は乗り物を表すクラスを作成します。今まで作成したCarクラスを乗り物(Vehicle)クラスとして、加速処理部分を抽象化したクラスを作成することとします。これにより加速部分はそれぞれの種類の乗り物によって定義することになります。Vehicleクラスを追加して、次のようにプログラムを記述してください。

Vehicle.vb

  1. Public MustInherit Class Vehicle
  2. 　'プロパティ==========
  3. 　Public Property Speed As Integer
  4. 　Public Property Gas As Double
  6. 　'コンストラクタ==========
  7. 　Public Sub New()
  8. 　　Me.New(20)
  9. 　End Sub
  11. 　Public Sub New(gas As Double)
  12. 　　Me.Speed = 0
  13. 　　Me.Gas = gas
  14. 　End Sub
  16. 　'メソッド==========
  17. 　'加速するメソッド(抽象メソッド)
  18. 　Public MustOverride Sub SpeedUp(sp As Integer)
  20. 　'減速するメソッド
  21. 　Public Sub SpeedDown(sp As Integer)
  22. 　　'スピードを減らす
  23. 　　Me.Speed -= sp
  24. 　　If Me.Speed < 0 Then 'スピードがマイナスになる場合
  25. 　　　'スピードを0に補正する
  26. 　　Me.Speed = 0
  27. 　　End If
  28. 　End Sub
  29. End Class

○　クラス図

○　解説

　18行目では、抽象メソッドを宣言しています。メソッドの仕様は決まっているので、このメソッドを使用するにはオーバーライドして処理を実装する必要があります。抽象メソッドが含まれるために1行目のクラスの宣言に「MustInherit」キーワードがついており、抽象クラスとして作成しています。

○　プログラム

　次に、乗り物クラスを継承したスポーツカークラスを作成しましょう。

SportsCar.vb

  1. Public Class SportsCar
  2. 　Inherits Vehicle
  4. 　'フィールド==========
  5. 　Public Const MAXSPEED As Integer = 300　　　　　'最大スピード
  6. 　Public Const MAXFUEL As Double = 60　　　　　'ガソリンタンク容量
  8. 　'コンストラクタ==========
  9. 　Public Sub New(gas As Double)
  10. 　　MyBase.New(gas)
  11. 　　'ガソリン量が容量を超える場合は、最大容量をガソリン量にセット
  12. 　　If Me.Gas > MAXFUEL Then
  13. 　　　Me.Gas = MAXFUEL
  14. 　　End If
  15. 　End Sub
  17. 　'メソッド==========
  18. 　Public Overrides Sub SpeedUp(sp As Integer)
  19. 　　'ガソリンを減らす
  20. 　　Me.Gas -= sp / 10.0
  22. 　　If Me.Gas < 0 Then 'ガソリンがマイナスになる場合
  23. 　　　'ガソリンを0に補正し、スピードを増やさない
  24. 　　　Me.Gas = 0
  25. 　　Else
  26. 　　　'スピードを増やす
  27. 　　　Me.Speed += sp
  28. 　　　If Me.Speed > MAXSPEED Then　　　　　'最大スピードに達した場合
  29. 　　　　　'最大スピードをセットする
  30. 　　　　　Me.Speed = MAXSPEED
  31. 　　　　End If
  32. 　　End If
  33. 　End Sub
  34. End Class

○　クラス図

○　解説

　5行目と6行目では最大スピードと、ガソリンタンク容量を定数として宣言しています。

　9~15行目ではコンストラクタを定義しています。このコンストラクタはガソリン量を受けとって、スーパークラスのコンストラクタを呼び出し、ガソリン量をセットしています。そのあと、ガソリンタンク容量と比較して、セットしたガソリン量が多ければ最大容量をセットするという処理をします。

　18~32行目ではSpeedUpメソッドをオーバーライドしています。抽象クラスを継承すると、抽象メソッドは必ずオーバーライドしなければならないという義務が発生します。今回は加速するときに、消費するガソリン量がない場合は加速しない、最大スピードに達していた場合はそれよりスピードが出ないようにしています。

○　プログラム

　では次にSportsCarクラスを利用するプログラムを作成しましょう。次のように記述してください。

Module1.vb

  1. Module Module1
  3. 　'車の状態を表示するメソッド
  4. 　Public Sub ShowMeter(car As SportsCar)
  5. 　　'コンソールの表示を消す
  6. 　　Console.Clear()
  8. 　　'各プロパティの内容を表示する
  9. 　　Console.WriteLine("スピード：{0}km/h", car.Speed)
  10. 　　Console.WriteLine("ガソリン：{0}L", car.Gas)
  11. 　End Sub
  13. 　Sub Main()
  14. 　　'インスタンス生成
  15. 　　Dim car As New SportsCar(60)
  17. 　　'状態を表示
  18. 　　ShowMeter(car)
  20. 　　While True
  21. 　　　'操作を入力
  22. 　　　Console.Write("1)加速　2)減速　9)終了：")
  23. 　　　Dim inputdata As String = Console.ReadLine()
  25. 　　　'操作によって分岐する
  26. 　　　Select Case inputdata
  27. 　　　　Case "1"
  28. 　　　　　'加速する
  29. 　　　　　car.SpeedUp(10)
  30. 　　　　　ShowMeter(car)
  31. 　　　　Case "2"
  32. 　　　　　'減速する
  33. 　　　　　car.SpeedDown(5)
  34. 　　　　　ShowMeter(car)
  35. 　　　　Case "9"
  36. 　　　　　'プログラムを終了する
  37. 　　　　　Return
  38. 　　　　Case Else
  39. 　　　　　ShowMeter(car)
  40. 　　　End Select
  41. 　　End While
  42. 　End Sub
  44. End Module

○　解説

　29行目では、SportsCarオブジェクトのSpeedUpメソッドを呼び出しています。このメソッドはSportsCarクラスでオーバーライドされています。それにより、SportsCarで定義されているSpeedUpが実行されます。

○　実行結果

スピード：300km/h
ガソリン：29L
1) 加速　2)減速　9)終了：

前へ   次へ